LINGO简单使用

一. 前言

1.1 简介

LINGO is a comprehensive tool designed to make building and solving Linear, Nonlinear (convex & nonconvex/Global), Quadratic, Quadratically Constrained, Second Order Cone, Semi-Definite, Stochastic, and Integer optimization models faster, easier and more efficient. LINGO provides a completely integrated package that includes a powerful language for expressing optimization models, a full featured environment for building and editing problems, and a set of fast built-in solvers.

在当下各种近乎于浮夸的("大")数据处理工具面前, lingo可谓是一个另类的存在, 其官网上也没有各种高大上的宣传概念(动辄大数据, 神经网络..机器学习...), 是个相当相当低调的数学处理工具, 甚至其操作界面至今还维持上古时代vb的极简风格.

(但是, 需要注意, 这并不意味着这个软件的开发的停止..这个软件还持续更新, 当下版本20)

官方文档

(图: 操作界面对于使用vba的用户可谓是相当亲切.)

专注解决以下数学问题:

• 线性
• 非线性(凹/凸/全局)
• 二次
• 二次约束
• 二阶锥规划
• 半确定
• 随机

知乎-二阶锥规划

知乎-「Stochastic」与「Random」有何区别?

二. 基本使用

2.1 操作界面

除了求解器的设置之外, 没有任何其他的乱七八糟的设置...nice!

至繁归于至简

2.2 基本规范

• LINGO数学规划模型, 通常包含包含三个基本部分: 目标函数, 决策变量, 约束条件.
• 每个语句都必须要用一个英文状态下的分号结束 一个语句可以分几行输入.
• 注释以英文状态的! 开始 必须以英文状态下的分号结束.
• 变量不区分字母的大小写 必须以字母开头 可以包含数字和下划线 不超过32 个字符.
• 程序只要定义好集合后, 其他语句的顺序是任意的.
• 函数以@开头.
• 默认所有的变量都是非负的.

2.2.1 段

• 集合段: 用于定义数组型性变量SETS: …… ENDSETS.
• 数据段: 用于变量赋值与数据传递DATA: ……ENDDATA.
• 目标与约束段: 用于列出目标与约束唯一一个没有段的开始和结束标记.
• 计算段: 用于数据初始整理计算CALC: …… ENDCALC.
• 初始段: 用于变量赋初值迭代寻优INIT: ……ENDINIT.
• 子模型段: 用于表达子模型进行调用@SUBMODEL mymodel:可执行语句( 约束+目标) ENDSUBMODEL.

2.3 集合

语法结构
sets:
集合名称1/成员列表1/: 属性1_1 属性1_2 … 属性1_n1;
集合名称2/成员列表2/: 属性2_1 属性2_2 … 属性2_n2;
派生集合名称( 集合名称1 集合名称2) : 属性3_1 … 属性3_n3;
endsets

sets:
    product/A B/;
    machine/M N/;
    week/1…2/;
    allowed(product,machine,week):x;
endsets

集合 name/n1…n4/:a;

• name是集合名 n1…n4表示集合内到四个成员

• a是集合属性

• 集合定义以语句" sets:" 开始 " endsets" 结束 " endsets" 单独成一行 后面不加标点符号

• !举例;
  sets:!集合段; 
  s/1..100/: x;
  endsets
  !目标与约束段
  @sum(s(i):x(i))<90;!循环求和函数
  

• 缺省属性的集合: work/w1w2w3/;

• 初始集合: name work

• 派生集合: links(name,work):b;

  • links成员取name和work的所有可能组合 是一个由12个成员构成的矩阵
  • 该矩阵的行数与name中的成员个数相等
  • 该矩阵的列数与work中的成员个数相等

@in(set_name,primitive_index_1[,primitive_index_2,...])

如果元素在指定集内则返回1 否则返回0;

sets:                          全集为I,C为B的补集
  I/x1..x4/;
  B(I)/x2/;
  C(I)|#not#@in(B&1):;
endsets

@index([set_name,]primitive_set_element)

该函数返回在集set_name中原是集成员primitive_set_element的索引. 如果set_name被忽略 那么它将返回第一个原是集成员的索引.

sets:                 如何确定集成员( B,Y)属于派生集S3
  S1/A B C/;
  S2/X Y Z/;
  S3(S1,S2)/A X,A Z,B,Y,C X/;
endsets
X= @in(S3,@index(S1,B),@index(S2,Y));

2.4 数据

语法结构

data: data:
属性 1= 数据列表; 数据列表; 数据列表;
属性 2= 数据列表; 数据列表; 数据列表;
enddata nddata

2.5 变量界定函数

@for(items(i):@bin(x(i)));

! 对x进行约束 0, 1;

变量界定函数实现对变量取值范围进行限制

2.6 循环函数

• @for: 该函数用来产生对成员的约束(类似C/C++中的for循环用法)

  @for(集合( 下标) [|逻辑表达式] :  集合表达式);
  

  表达方式	示例
  数学表达式
  Lingo编码	@for(node(i) : x(i) < 10);
  Latex编码	x(i) < 10; i \in {1,2,3}

  model:
  sets:
    number/1..5/:x;
  endsets
    @for(number(I):x(I)=I^2);
  end
  

• @sum: 返回遍历指定成员的一个表达式的和

  @sum(集合( 下标) : 集合表达式)
  

  表达方式	示例
  数学表达式
  Lingo编码	min = @sum(arc(i,j) : x(i) * d(i,j));
  Latex编码	min = \sum_{i = 1}{3}\sum_{j=1}{3}x(i)*d(i,j)

  # 计算前五位数的和
  
  model:
  data:
  	N=6;
  enddata
  sets:
  	number/1..N/:x;
  endsets
  data:
  	x = 5 1 3 4 6 10;
  enddata
  	s = @sum(number(I)| I #le#5 :x);
  end
  

  # 计算元素中小于或等于5数的和
  
  model:
  data:
  	N=6;
  enddata
  sets:
  	number/1..N/:x;
  endsets
  data:
  	x = 5 1 3 4 6 10;
  enddata
  	s = @sum(number(I) | x(i) #le# 5: x(i));
  end
  

• @min: 返回指定成员的一个表达式的最小值

  model:
  data:
    N=6;
  enddata
  sets:
    number/1  N/:x;
  endsets
  data:
    x=5 1 3 4 6 10;
  enddata
    minv=@min(number(I)|I #le# 5:x;
  

• @max: 返回指定成员的一个表达式的最大值

2.7 其他函数

• @if(logical_condition,true_result,false_result): 一个逻辑表达式logical_condition 如果为真返回true_ result 否则返回false_result.

2.8 数学运算符

＾  次幂
*   乘
／  除
﹢  加
﹣  减

2.9 逻辑运算符

在 LINGO 中逻辑运算符主要用于集循环函数的条件表达式中, 用来控制在函数中哪些集成员被包含, 哪些被排斥. 在创建稀疏集时用在成员资格过滤器中. LINGO具有９种逻辑运算符

优先级由高到低

高 #not#

\#eq# #ne# #gt# #ge# #lt# #le#

低 #and# #or#

2.10 数学函数

三. 示例

3.1 基本

$\sum_{i=1}^{100}\sum_{j=1}^{200} = 280$

model:
	sets:
		a/1..100/:;
		b/1..200/:;
		c(a, b):x;
	endsets

	@sum(c(i, j):x(i, j)) = 280;
end

3.1.1 示例1

$最为常见的模型求解:\\ max\;z = 2x_1 + 3x_2 - 5x_3\\ s.t = \begin{cases} x_1 + x_2 + x_3 = 7\\ 2x_1 - 5x_2 + x_3 \geq 10\\ x_1 + 3x_2 + x_3 \leq 12\\ x_1, x_20, x_3 \geq 0 \end{cases}\\$

# 这也是lingo的一大优势
# 代码即模型

model:
	max = 2 * x1 + 3 * x2 - 5 * x3;
	x1 + x2 + x3 = 7;
	2 * x1 - 5 * x2 + x3 >= 10;
	x1 + 3 * x2 + x3 <= 12;
	x1 >= 0;
	x2 >= 0;
	x3 >= 0;
end

# python下的实现

from scipy import optimize

# * -1, 转换为min
z = [-2, -3, 5]

a = [
    [1, 1, 1],
    # * -1, 转换为小于等于
    [-2, 5, -1],
    [1, 3, 1]
]

b = [
    7, -10, 12
]
x1b = (0, None)
x2b = (0, None)
x3b = (0, None)

optimize.linprog(
    z,
    A_ub=a, b_ub=b,
    bounds=[x1b, x2b, x3b],
    method='revised simplex'
)

model:
max = 2 * x1 + 3 * x2 - 5 * x3;
x1 + x2 + x3 = 7;
2 * x1 - 5 * x2 + x3 >= 10;
x1 + 3 * x2 + x3 <= 12;
x1 >= 0;
x2 >= 0;
x3 >= 0;
@gin(x1);
@gin(x2);
@gin(x3); !增加一个整数的约束;
end

3.1.2 示例2

$min = \sqrt{x^2 + y^ 2 + z^ 2}\\ s.t =\begin{cases} x + y + z = 1\\ z = x^ 2 + y ^ 2 \end{cases}$

model:
min=(x^2+y^2+z^2)^(1/2);
x+y+z=1;
z=x^2+y^2;
@free(x); @free(y);
end

from scipy import optimize
import math

# 目标函数
f = lambda args : math.sqrt(sum(arg ** 2 for arg in args))

# 约束条件
cons = (
    {'type': 'eq', 'fun': lambda args: sum(args) - 1},
    {'type': 'eq', 'fun': lambda args: args[0] ** 2 + args[1] ** 2 - args[2]}
)

optimize.minimize(f, (0, 0, 0), constraints=cons)

     fun: 0.5828773135364937
     jac: array([0.62796304, 0.62796304, 0.45970085])
 message: 'Optimization terminated successfully'
    nfev: 20
     nit: 5
    njev: 5
  status: 0
 success: True
       x: array([0.36602541, 0.3660254 , 0.26794919])

3.2 模型

3.2.1 示例1

背包问题

假设存在背包, 最大的载重量为30, 10种不同的商品, 各种商品只存在1, 0两种选择, 即装1件, 或者不装

如何装载商品实现收益最大化

$数学模型简化如下:\\ max = \sum_{i=1}^{10}p_i * x_i\\ s.t = \begin{cases} \sum_{i=1}^{10} w_i* x_i \leq 30\\ x_i \in{\{0, 1\}}, \;i = 1, 2, 3...10 \end{cases}\\ p_i, 为利润\\ w_i, 为重量\\ x_i, 装载与否\\$

model:

	sets:
		items/1 2 3 4 5 6 7 8 9 10/: weight, profit, x;
	endsets

	data:
		weight = 6 3 4 5 1 2 3 5 4 2;
		profit = 540 200 180 350 60 150 280 450 320 120;
	enddata

	max = @sum(items(i): profit(i) * x(i));
	@sum(items(i): weight(i) * x(i)) <=30;
	@for(items(i):@bin(x(i)));
end

3.2.2 示例2

某公司有6个建筑工地 位置坐标为(ai, bi), 水泥日用量di

i 1 2 3 4 5 6
a 1.25 8.75 0.5 5.75 3 7.25
b 1.25 0.75 4.75 5 6.5 7.75
d 3 5 4 7 6 11

• 现有2料场, 位于A (5, 1), B (2, 7),记(x_j, y_j), j=1,2, 日储量e_j各有20吨.
  假设料场和工地之间有直线道路, 制定每天的供应计划, 即从A, B两个料场分别向各工地运送多少吨水泥使总距离最小.
  取决策变量c_ij表示 i 工地从 j 料场运来的水泥量, 模型(线性模型) 如下:

  $min \sum_{j=1}^2\sum_{i=1}^6 c_{ij}\sqrt{(x_j-a_i) ^ 2 + (y_j - b_i) ^ 2}\\ s.t = \begin{cases} \sum_{j=1}^ 2 = d_i, i = 1, 2,...6\\ \sum_{i = 1} ^ 6 c_ij \leq eJ, j = 1, 2 \end{cases}$

  model:
  	sets:
  		demand/1..6/:a,b,d;
  		supply/1..2/:x,y,e;
  		link(demand,supply):c;
  	endsets
  	
  	data:
  		a=1.25 8.75 0.5 5.75 3 7.25;
  		b=1.25 0.75 4.75 5 6.5 7.75;
  		d=3 5 4 7 6 11;
  		x=5 2;
  		y=1 7;
  		e=20 20;
  	enddata
  	
  	[obj]min=@sum(link(i,j):c(i,j)*@sqrt((a(i)-x(j))^2+(b(i)-y(j))^2));!目标函数;
  	
  	@for(demand(i):@sum(supply(j):c(i,j))=d(i));
  	@for(supply(j):@sum(demand(i):c(i,j))<=e(j));
  end
  

• 改建两个新料场 需要确定新料场位置(xj, yj)和运量c_ij 在其它条件不变下使总距离数最小.
  模型还是一样, 未知量变为料场位置(xj, yj) 和运量 c_ij 变为非线性优化问题.

  model:
  	sets:
  		demand/1..6/:a,b,d;
  		supply/1..2/:x,y,e;
  		link(demand,supply):c;
  	endsets
  	
  	data:
  		a=1.25 8.75 0.5 5.75 3 7.25;
  		b=1.25 0.75 4.75 5 6.5 7.75;
  		d=3 5 4 7 6 11;
  		e=20 20;
  	enddata
  	
  	init:
  		x=5 2;
  		y=1 7;
  	endinit
  	
  	[obj]min=@sum(link(i,j):c(i,j)*@sqrt((a(i)-x(j))^2+(b(i)-y(j))^2));!目标函数;
  	
  	@for(demand(i):@sum(supply(j):c(i,j))=d(i));
  	@for(supply(j):@sum(demand(i):c(i,j))<=e(j));
  	@for(supply:@free(x);@free(y));
  end
  

四. 错误对照表

五. 在线文档

六. 参考

• 运筹优化学习01: Lingo入门与错误列表分析
• 【数学建模】Lingo软件介绍+常用函数总结+样例
• LINGO语法及软件操作